당일 단타에 최적인 SPY(SPDR S&P 500 ETF) 1분 차트 전략

VWAP, MFI, RSI with S/R 전략 해설

VWAP (Volume-Weighted Average Price): 거래량 가중 평균 가격
시장의 평균 거래 가격을 거래량으로 가중하여 계산한 값입니다. 일반적으로 시장의 전반적인 트렌드를 파악하는 데 사용됩니다.

MFI (Money Flow Index): 자금 흐름 지수
거래량을 고려하여 계산되는 상대 강도 지수(RSI)의 일종으로, 주식이 과매수 또는 과매도 상태인지를 나타내는 지표입니다.

RSI (Relative Strength Index): 상대 강도 지수
주식의 가격 상승 및 하락의 강도를 나타내는 지표로, 특정 기간 동안의 가격 변동을 기반으로 과매수 또는 과매도 상태를 나타냅니다.

S/R (Support/Resistance): 지지선/저항선
주식 가격의 움직임에서 가격이 반등하는 경향이 있는 최저 가격 수준(지지선)과 가격이 하락하는 경향이 있는 최고 가격 수준(저항선)을 의미합니다.

 

VWAP, MFI, RSI with S/R 전략

이 전략은 SPY의 1분 차트에서 가격 추세의 잠재적인 반전 지점을 파악하는 데 목표를 두고 있습니다. 여기에는 모멘텀 지표(RSI 및 MFI), 거래량 가중 평균 가격(VWAP), 최근 가격 행동 추세를 결합하여 사용합니다. 이 전략은 가격이 반전될 조건, 즉 잠재적 상승 추세에서 지지선을 통한 반등이나 잠재적 하락 추세에서 저항선에서의 하락을 찾습니다.
가격 수준 분석(지지/저항)과 모멘텀 지표를 결합함으로써, 최근 가격 움직임과 역사적 고점 및 저점에 대한 현재 가격의 위치를 고려하여 중요한 추세 반전을 식별할 가능성을 높이려고 합니다.

 

VWAP (거래량 가중 평균 가격)

VWAP는 일반적인 시장 추세를 결정하는 기준으로 사용됩니다. 거래량으로 가중된 평균 가격입니다.
VWAP 이상의 가격은 일반적으로 강세로 간주되며, VWAP 이하의 가격은 약세로 여겨집니다.

MFI (머니 플로우 지수) 및 RSI (상대 강도 지수) 매개변수

MFI는 거래량 가중 RSI로, 과매수(70 이상) 또는 과매도(30 이하) 상태를 식별하는 데 사용됩니다.
RSI는 최근 가격 변화의 크기를 측정하여 과매수 또는 과매도 조건을 식별하는 모멘텀 지표입니다.
이 스크립트는 MFI와 RSI 모두에 대해 표준 과매수(70) 및 과매도(30) 임계값을 사용합니다.

추세 확인 기능

trendCheck 함수는 과거 pastBars 캔들을 분석하여 상승(종가가 시가보다 높음) 및 하락(종가가 시가보다 낮음) 캔들의 수를 계산합니다.
이 기능은 최근 추세 방향을 평가하는 데 사용됩니다.

지지 및 저항 탐지

스크립트는 최근 lookbackSR (50) 기간 동안 최고점과 최저점을 계산하여 잠재적인 지지 및 저항 수준을 식별합니다.
isNearSupport 및 isNearResistance는 현재 가격이 이러한 식별된 수준의 0.08% 이내에 있는지 확인하는 조건입니다.

매수 및 매도 로직

매수 신호:

• RSI가 과매도 임계값(30)을 넘어섰을 때.
• MFI도 과매도 수준(30) 이하일 때.
• 현재 가격이 VWAP 이상일 때.
• 최근 추세(과거 20 바)가 주로 하락했을 때.
• 가격이 식별된 지지 수준에 근접했을 때.

매도 신호:

• RSI가 과매수 임계값(70) 아래로 떨어졌을 때.
• MFI가 과매수 수준(70) 이상일 때.
• 현재 가격이 VWAP 이하일 때.
• 최근 추세가 주로 상승했을 때.
• 가격이 식별된 저항 수준에 근접했을 때.

 

이 전략은 시장의 미묘한 변동을 포착하고, 짧은 시간 내에 이익을 얻기 위해 설계되었습니다. 하지만 모든 투자에는 위험이 따르므로, 이 전략을 사용하기 전에 충분한 연구와 함께 자신만의 위험 관리 전략을 세우는 것이 중요합니다.

 

//@version=5
indicator("VWAP, MFI, RSI with S/R Strategy", shorttitle="VMR Sup/res", overlay=true)

// VWAP
vwap = ta.vwap(0)

// MFI Parameters
mfiLength = 14
mfiOverbought = 70
mfiOversold = 30
mfi = ta.mfi(close, mfiLength)

// RSI Parameters
rsiLength = 14
rsiOverbought = 70
rsiOversold = 30
rsi = ta.rsi(close, rsiLength)

// Trend Check Function
trendCheck(pastBars) =>
    bullish = 0
    bearish = 0
    for i = 0 to pastBars - 1
        if close[i] > open[i]
            bullish := bullish + 1
        else
            bearish := bearish + 1
    [bullish, bearish]

// Support and Resistance Detection
lookbackSR = input(50, title="Lookback Period for S/R")
highestHigh = ta.highest(high, lookbackSR)
lowestLow = ta.lowest(low, lookbackSR)
isNearSupport = close < lowestLow * (1 + 0.0008) // Within 0.08% of the lowest low
isNearResistance = close > highestHigh * (1 - 0.0008) // Within 0.08% of the highest high

// Check past 10 candles
[pastBullish, pastBearish] = trendCheck(20)

// Buy and Sell Logic with S/R Check
buySignal = ta.crossover(rsi, rsiOversold) and (mfi < mfiOversold) and (close > vwap) and (pastBearish > pastBullish) and isNearSupport
sellSignal = ta.crossunder(rsi, rsiOverbought) and (mfi > mfiOverbought) and (close < vwap) and (pastBullish > pastBearish) and isNearResistance

// Plotting
plotshape(buySignal, title="Buy Signal", location=location.belowbar, color=color.green, style=shape.labelup, text="BUY")
plotshape(sellSignal, title="Sell Signal", location=location.abovebar, color=color.red, style=shape.labeldown, text="SELL")

 

Live stock, index, futures, Forex and Bitcoin charts on TradingView